Μετάβαση στο περιεχόμενο

Ρυθμίσεις cookies

Επιλέξτε ανά κατηγορία ποια cookies επιτρέπετε. Μπορείτε να αλλάξετε την επιλογή σας οποιαδήποτε στιγμή μέσω των Ρυθμίσεων cookies στο κάτω μέρος κάθε σελίδας. Δήλωση απορρήτου

Απαραίτητα

Πάντα ενεργά

Χρειάζονται για τη σύνδεση, για να διατηρείται το καλάθι σας και για να θυμόμαστε τις επιλογές σας. Είναι πάντα ενεργά.

Ποια cookies;
  • weboke_sessie, weboke_klant, weboke_remember: η συνεδρία σας και η παραμονή σε σύνδεση
  • weboke_basket: το καλάθι σας
  • wkBtwIncl: εμφάνιση τιμών με ή χωρίς ΦΠΑ
  • wok_cookies: η επιλογή σας για τα cookies, 12 μήνες

Μετρούν ποια διαφήμιση οδηγεί σε επίσκεψη ή παραγγελία, ώστε να μην πληρώνουμε για διαφημίσεις που δεν αποδίδουν.

Ποια cookies;
  • Google Ads μέσω Google Tag Manager (_gcl_au, _gcl_aw), έως 90 ημέρες
  • OpenAI Ads, διαφημίσεις στο ChatGPT
  • wok_aff: μέσω ποιου συνεργάτη ήρθατε σε εμάς (πρόγραμμα συνεργατών), 60 ημέρες

4,6

Χώρα και γλώσσα

Κάθε χώρα έχει τη δική της ιστοσελίδα, με τιμές και ΦΠΑ της χώρας αυτής.

Προβολή

Σύγκριση δύο λιστών: ποιος υπάρχει στη μία και όχι στην άλλη;

Η λίστα μελών σε σύγκριση με τις πληρωμές, οι πελάτες της περσινής χρονιάς σε σύγκριση με τους φετινούς, η λίστα αποθέματος σε σύγκριση με την παραγγελία: θέλετε να μάθετε ποιος υπάρχει στη μία λίστα και όχι στην άλλη. Το άρθρο Εύρεση και αφαίρεση διπλών πελατών εντοπίζει διπλότυπα μέσα σε μία λίστα. Εδώ συγκρίνετε δύο λίστες μεταξύ τους.

Ως παράδειγμα χρησιμοποιούμε το Bakkerij De Korenaar με δύο φύλλα εργασίας: το Klanten2025 με τις διευθύνσεις email της περσινής χρονιάς στα A2:A8 και το Klanten2026 με τις φετινές στα A2:A7.

Τρόπος 1: μια βοηθητική στήλη με «έφυγε» ή «παραμένει»

Στο φύλλο εργασίας Klanten2025 πληκτρολογήστε στο B2:

=IF(COUNTIF(Klanten2026!$A$2:$A$7;A2)=0;"έφυγε";"παραμένει")

Σύρετε τον τύπο προς τα κάτω μέχρι τον τελευταίο πελάτη. Η COUNTIF μετρά πόσες φορές εμφανίζεται η διεύθυνση στη λίστα του 2026. Αν το αποτέλεσμα είναι 0, ο πελάτης έφυγε. Στη συνέχεια μπορείτε να φιλτράρετε ή να ταξινομήσετε τη στήλη B (δείτε Ταξινόμηση και φιλτράρισμα).

Τα σύμβολα του δολαρίου είναι σημαντικά: χωρίς αυτά, η περιοχή της άλλης λίστας μετατοπίζεται καθώς σύρετε τον τύπο και οι επάνω διευθύνσεις χάνονται από τον έλεγχο στο κάτω μέρος.

Τρόπος 2: μια λίστα μόνο με τις διαφορές

Σε ξεχωριστό φύλλο εργασίας, η FILTER δημιουργεί με μία κίνηση μια λίστα με όλους τους πελάτες που έφυγαν:

=FILTER(Klanten2025!A2:A8;COUNTIF(Klanten2026!A2:A7;Klanten2025!A2:A8)=0;"κανείς δεν έφυγε")

Εδώ η COUNTIF λαμβάνει ολόκληρη λίστα ως δεύτερο όρισμα και μετρά ταυτόχρονα για κάθε διεύθυνση του 2025. Η FILTER κρατά τις διευθύνσεις για τις οποίες το αποτέλεσμα είναι 0. Τους νέους πελάτες τους βρίσκετε αντιστρέφοντας τις λίστες:

=FILTER(Klanten2026!A2:A7;COUNTIF(Klanten2025!A2:A8;Klanten2026!A2:A7)=0;"κανείς νέος")

Πελάτες που έφυγαν και νέοι πελάτες δίπλα δίπλα
Πελάτες που έφυγαν (1) και νέοι πελάτες (2), ο καθένας με έναν τύπο FILTER

Όσους υπάρχουν σε μία μόνο από τις δύο λίστες, νέους ή πελάτες που έφυγαν, τους βρίσκετε με:

=UNIQUE(VSTACK(Klanten2025!A2:A8;Klanten2026!A2:A7);;1)

Η VSTACK τοποθετεί τις δύο λίστες τη μία κάτω από την άλλη. Η UNIQUE με 1 ως τρίτο όρισμα κρατά μόνο τις τιμές που εμφανίζονται ακριβώς μία φορά. Αν μια διεύθυνση εμφανίζεται ήδη διπλή μέσα σε μία λίστα, κάντε πρώτα μοναδικές τις τιμές αυτής της λίστας: =UNIQUE(VSTACK(UNIQUE(Klanten2025!A2:A8);UNIQUE(Klanten2026!A2:A7));;1).

Τρόπος 3: χρώματα αντί για λίστες

  1. Στο φύλλο εργασίας Klanten2025 επιλέξτε τις διευθύνσεις, A2:A8.
  2. Στην καρτέλα Αρχική επιλέξτε Μορφοποίηση υπό όρους, Νέος κανόνας, τύπος Τύπος.
  3. Πληκτρολογήστε =COUNTIF(Klanten2026!$A$2:$A$7;$A2)=0, επιλέξτε ένα χρώμα γεμίσματος και κάντε κλικ στο OK.

Η αναφορά σε άλλο φύλλο εργασίας μέσα σε έναν κανόνα μορφοποίησης λειτουργεί κανονικά στο Euro-Office. Σε παλιές εκδόσεις του Excel χρειαζόταν ένα καθορισμένο όνομα.

Οι πελάτες που έφυγαν χρωματισμένοι
Οι διευθύνσεις που δεν εμφανίζονται πλέον το 2026 χρωματίζονται πορτοκαλί. Η στήλη B δείχνει αν ο πελάτης έφυγε ή παραμένει

Παγίδες

  • Κενά διαστήματα: το "info@dekorenaar.nl " με ένα κενό στο τέλος είναι για το υπολογιστικό φύλλο μια διαφορετική διεύθυνση. Αφαιρέστε πρώτα τα κενά με την TRIM σε μια βοηθητική στήλη.
  • Τα κενά κελιά μιας περιοχής μετρούν επίσης ως τιμή. Συμπεριλάβετε λοιπόν μόνο τις γραμμές με δεδομένα ή φιλτράρετε τα κενά κελιά με <>"".
  • Αριθμοί έναντι κειμένου: αν συγκρίνετε αριθμούς πελατών και ο αριθμός είναι αποθηκευμένος στη μία λίστα ως κείμενο (στοιχισμένος αριστερά στο κελί) και στην άλλη ως αριθμός, δεν θα ταιριάξουν. Δείτε Η VLOOKUP επιστρέφει #N/A: πώς να το λύσετε.
  • Ως τρίτο όρισμα της UNIQUE χρησιμοποιήστε TRUE, TRUE() ή 1. Το Euro-Office στα ελληνικά εμφανίζει τα αγγλικά ονόματα συναρτήσεων (δείτε Μεταφορά τύπων από το Excel: αγγλικά ονόματα συναρτήσεων και το ερωτηματικό).

Μια στιγμή…

Ρυθμίστε τα domains σας

Ρυθμίστε για κάθε domain τους nameservers, τη σύνδεση με το hosting σας και ποιος θα είναι ο κάτοχος.

Φόρτωση των domains σας…