Μετάβαση στο περιεχόμενο

Ρυθμίσεις cookies

Επιλέξτε ανά κατηγορία ποια cookies επιτρέπετε. Μπορείτε να αλλάξετε την επιλογή σας οποιαδήποτε στιγμή μέσω των Ρυθμίσεων cookies στο κάτω μέρος κάθε σελίδας. Δήλωση απορρήτου

Απαραίτητα

Πάντα ενεργά

Χρειάζονται για τη σύνδεση, για να διατηρείται το καλάθι σας και για να θυμόμαστε τις επιλογές σας. Είναι πάντα ενεργά.

Ποια cookies;
  • weboke_sessie, weboke_klant, weboke_remember: η συνεδρία σας και η παραμονή σε σύνδεση
  • weboke_basket: το καλάθι σας
  • wkBtwIncl: εμφάνιση τιμών με ή χωρίς ΦΠΑ
  • wok_cookies: η επιλογή σας για τα cookies, 12 μήνες

Μετρούν ποια διαφήμιση οδηγεί σε επίσκεψη ή παραγγελία, ώστε να μην πληρώνουμε για διαφημίσεις που δεν αποδίδουν.

Ποια cookies;
  • Google Ads μέσω Google Tag Manager (_gcl_au, _gcl_aw), έως 90 ημέρες
  • OpenAI Ads, διαφημίσεις στο ChatGPT
  • wok_aff: μέσω ποιου συνεργάτη ήρθατε σε εμάς (πρόγραμμα συνεργατών), 60 ημέρες

4,6

Χώρα και γλώσσα

Κάθε χώρα έχει τη δική της ιστοσελίδα, με τιμές και ΦΠΑ της χώρας αυτής.

Προβολή

Άθροιση εσόδων ανά μήνα ή ανά περίοδο με SUMIFS

Ένα βιβλίο ταμείου, μια λίστα πωλήσεων ή ένα αρχείο καταγραφής ωρών έχει μία ημερομηνία ανά γραμμή. Αυτό που θέλετε να μάθετε είναι το σύνολο ανά μήνα, ανά τρίμηνο ή μεταξύ δύο ημερομηνιών, ενδεχομένως και ανά προϊόν. Με τη SUMIFS και δύο συνθήκες ημερομηνίας δημιουργείτε μια τέτοια σύνοψη, η οποία παραμένει σωστή όταν προστίθενται γραμμές. Το ίδιο μπορεί να γίνει και με έναν συγκεντρωτικό πίνακα (δείτε Συγκεντρωτικός πίνακας ανά μήνα, τρίμηνο ή εβδομάδα). Η SUMIFS είναι πιο πρακτική όταν η σύνοψη πρέπει να διατηρεί σταθερή μορφή, για παράδειγμα για μια αναφορά ή έναν προϋπολογισμό.

Ως παράδειγμα χρησιμοποιούμε τις πωλήσεις του ανθοπωλείου Bloemisterij Het Zonnetje στο φύλλο εργασίας Verkoop: στη στήλη A η ημερομηνία, στη B το προϊόν, στη C η κατηγορία και στη D το ποσό, από τη γραμμή 2 έως και τη 300.

Βήμα 1: μια σειρά με μήνες

Δημιουργήστε ένα φύλλο εργασίας Σύνοψη. Αντί να πληκτρολογήσετε δώδεκα ημερομηνίες, ένας μόνο τύπος τις δημιουργεί όλες. Πληκτρολογήστε στο κελί A2:

=EDATE(DATE(2026;1;1);SEQUENCE(12;1;0))

Η SEQUENCE(12;1;0) δημιουργεί τους αριθμούς 0 έως και 11 και η EDATE προσθέτει αντίστοιχα τόσους μήνες στην 1η Ιανουαρίου 2026. Έτσι παίρνετε την πρώτη ημέρα κάθε μήνα, από το A2 έως και το A13. Δώστε στα κελιά A2:A13 την προσαρμοσμένη μορφή mmmm yyyy (μέσω Περισσότερες μορφές, Προσαρμογή, δείτε Eigen getalnotaties: "12 st", bedragen in duizenden, rood bij negatief), ώστε να εμφανίζεται Ιανουάριος 2026, Φεβρουάριος 2026 κ.ο.κ.

Η μορφή ημερομηνίας mmmm yyyy
Η προσαρμοσμένη μορφή mmmm yyyy εμφανίζει τον μήνα ολογράφως μαζί με το έτος

Βήμα 2: τα έσοδα ανά μήνα

Πληκτρολογήστε στο κελί B2:

=SUMIFS(Verkoop!$D$2:$D$300;Verkoop!$A$2:$A$300;">="&$A2;Verkoop!$A$2:$A$300;"<="&EOMONTH($A2;0))

Η SUMIFS αθροίζει τα ποσά για τα οποία η ημερομηνία είναι μεγαλύτερη ή ίση με την πρώτη ημέρα του μήνα και μικρότερη ή ίση με την τελευταία ημέρα (η EOMONTH με 0 επιστρέφει το τέλος του ίδιου μήνα). Σύρετε τον τύπο έως το B13 ή επιλέξτε τα B2:B13 πριν πληκτρολογήσετε και ολοκληρώστε με Ctrl+Enter.

Βήμα 3: ανά προϊόν

Τοποθετήστε ονόματα προϊόντων ως επικεφαλίδες το ένα δίπλα στο άλλο, για παράδειγμα Rozen στο C1, Tulpen στο D1 και Boeket στο E1, και πληκτρολογήστε στο C2:

=SUMIFS(Verkoop!$D$2:$D$300;Verkoop!$A$2:$A$300;">="&$A2;Verkoop!$A$2:$A$300;"<="&EOMONTH($A2;0);Verkoop!$B$2:$B$300;C$1)

Προστίθεται ένα ακόμη ζεύγος συνθηκών: το προϊόν πρέπει να είναι ίδιο με την επικεφαλίδα. Προσέξτε τα σύμβολα δολαρίου: το $A2 κλειδώνει τη στήλη με τους μήνες και το C$1 τη γραμμή με τις επικεφαλίδες. Έτσι ο ίδιος τύπος μπορεί να βρίσκεται σε όλη την περιοχή. Γρήγορος τρόπος: επιλέξτε πρώτα τα C2:E13, πληκτρολογήστε τον τύπο και πατήστε Ctrl+Enter. Το Euro-Office εισάγει τότε τον τύπο σε όλα τα επιλεγμένα κελιά, με τις αναφορές προσαρμοσμένες για κάθε κελί.

Έσοδα ανά μήνα και ανά προϊόν
Άθροιση ανά μήνα και ανά προϊόν. Στη γραμμή τύπων φαίνεται ο τύπος του C2, που μέσω του C$1 αναφέρεται στην επικεφαλίδα Rozen (1)

Καταμέτρηση αντί για άθροιση

Τον αριθμό των πωλήσεων ανά μήνα τον μετράτε με τις ίδιες συνθήκες και τη COUNTIFS:

=COUNTIFS(Verkoop!$A$2:$A$300;">="&$A2;Verkoop!$A$2:$A$300;"<="&EOMONTH($A2;0))

Μια ελεύθερη περίοδος

Βάλτε μια ημερομηνία έναρξης στο H1 και μια ημερομηνία λήξης στο I1. Τα έσοδα στο μεταξύ διάστημα, συμπεριλαμβανομένων και των δύο ημερών:

=SUMIFS(Verkoop!D:D;Verkoop!A:A;">="&H1;Verkoop!A:A;"<="&I1)

Συνήθεις παγίδες

  • Εισαγωγικά και &: η σύγκριση μπαίνει σε εισαγωγικά και το κελί ακολουθεί με &: ">="&H1. Αν πληκτρολογήσετε ">=H1", το Euro-Office αναζητά το κείμενο H1 και το αποτέλεσμα είναι 0.
  • Ημερομηνίες που περιέχουν ώρα (16/11/2026 14:32) την τελευταία ημέρα του μήνα μένουν εκτός της συνθήκης "<="&EOMONTH(...), επειδή αυτή αντιστοιχεί στα μεσάνυχτα. Σε αυτή την περίπτωση χρησιμοποιήστε ως δεύτερη συνθήκη "<"&EDATE($A2;1): μικρότερη από την πρώτη ημέρα του επόμενου μήνα.
  • Φιλτράρισμα μόνο με τον αριθμό του μήνα, για παράδειγμα με MONTH() σε βοηθητική στήλη, αθροίζει μαζί τον Ιανουάριο του 2025 και τον Ιανουάριο του 2026. Να λαμβάνετε πάντα υπόψη και το έτος.
  • Ημερομηνίες ως κείμενο δεν υπολογίζονται. Δείτε Ημερομηνίες που εισάγονται ως κείμενο ή με αντεστραμμένη ημέρα και μήνα.

Μια στιγμή…

Ρυθμίστε τα domains σας

Ρυθμίστε για κάθε domain τους nameservers, τη σύνδεση με το hosting σας και ποιος θα είναι ο κάτοχος.

Φόρτωση των domains σας…